Atelier 7 - "Simon Says"

Matériel

1 arduino uno
4 leds
16 fils male/male
4 boutons poussoir
1 buzzer
4 résistances 220

"Simon Says", c'est quoi ?

"Simon Says" est un jeu de mémoire. On lance le jeu en appuyant sur un des boutons.

Quand une led s'allume on appuie sur le bouton correspondant, et on répète la séquence lumineuse/musicale. La séquence est de plus en plus longues.

Le jeu peut être gagné si on va au bout des 13 rounds.

Ce que vous allez devoir faire ?

Générer une séquence random, qui jouera de la musique et allumera les leds.

Les branchements

Définir les constantes

Etape 1

Les notes

Il faut déclarer les notes que va jouer le buzzer

/*************************************************
* Public Constants
*************************************************/
#define NOTE_B0 31
#define NOTE_C1 33
#define NOTE_CS1 35
#define NOTE_D1 37
#define NOTE_DS1 39
#define NOTE_E1 41
#define NOTE_F1 44
#define NOTE_FS1 46
#define NOTE_G1 49
#define NOTE_GS1 52
#define NOTE_A1 55
#define NOTE_AS1 58
#define NOTE_B1 62
#define NOTE_C2 65
#define NOTE_CS2 69
#define NOTE_D2 73
#define NOTE_DS2 78
#define NOTE_E2 82
#define NOTE_F2 87
#define NOTE_FS2 93
#define NOTE_G2 98
#define NOTE_GS2 104
#define NOTE_A2 110
#define NOTE_AS2 117
#define NOTE_B2 123
#define NOTE_C3 131
#define NOTE_CS3 139
#define NOTE_D3 147
#define NOTE_DS3 156
#define NOTE_E3 165
#define NOTE_F3 175
#define NOTE_FS3 185
#define NOTE_G3 196
#define NOTE_GS3 208
#define NOTE_A3 220
#define NOTE_AS3 233
#define NOTE_B3 247
#define NOTE_C4 262
#define NOTE_CS4 277
#define NOTE_D4 294
#define NOTE_DS4 311
#define NOTE_E4 330
#define NOTE_F4 349
#define NOTE_FS4 370
#define NOTE_G4 392
#define NOTE_GS4 415
#define NOTE_A4 440
#define NOTE_AS4 466
#define NOTE_B4 494
#define NOTE_C5 523
#define NOTE_CS5 554
#define NOTE_D5 587
#define NOTE_DS5 622
#define NOTE_E5 659
#define NOTE_F5 698
#define NOTE_FS5 740
#define NOTE_G5 784
#define NOTE_GS5 831
#define NOTE_A5 880
#define NOTE_AS5 932
#define NOTE_B5 988
#define NOTE_C6 1047
#define NOTE_CS6 1109
#define NOTE_D6 1175
#define NOTE_DS6 1245
#define NOTE_E6 1319
#define NOTE_F6 1397
#define NOTE_FS6 1480
#define NOTE_G6 1568
#define NOTE_GS6 1661
#define NOTE_A6 1760
#define NOTE_AS6 1865
#define NOTE_B6 1976
#define NOTE_C7 2093
#define NOTE_CS7 2217
#define NOTE_D7 2349
#define NOTE_DS7 2489
#define NOTE_E7 2637
#define NOTE_F7 2794
#define NOTE_FS7 2960
#define NOTE_G7 3136
#define NOTE_GS7 3322
#define NOTE_A7 3520
#define NOTE_AS7 3729
#define NOTE_B7 3951
#define NOTE_C8 4186
#define NOTE_CS8 4435
#define NOTE_D8 4699
#define NOTE_DS8 4978

Le choix des leds et des boutons

Il faut déclarer les leds et les boutons pour pouvoir les contrôler

#define CHOICE_OFF      0 //Utilisé pour contrôler les leds
#define CHOICE_NONE     0 //Utilisé pour checker les boutons
#define CHOICE_RED  (1 << 0)
#define CHOICE_GREEN    (1 << 1)
#define CHOICE_BLUE (1 << 2)
#define CHOICE_YELLOW   (1 << 3)

déclaration des pins

Pour que notre Arduino sache où sont connectés nos composants

// déclaration des pins des leds
#define LED_RED     10
#define LED_GREEN   3
#define LED_BLUE    13
#define LED_YELLOW  5

// déclaration des pins des boutons
#define BUTTON_RED    9
#define BUTTON_GREEN  2
#define BUTTON_BLUE   12
#define BUTTON_YELLOW 6

// déclaration des pins du buzzer
#define BUZZER1  4
#define BUZZER2  7

définition des paramètres du jeu

Pour que nous sachions en combien de rounds on joue et le temps limite qu'on a pour appuyer sur les boutons.

// définir les paramètres du jeu
#define ROUNDS_TO_WIN      13 //Nombre de rounds à faire pour gagner. 13 est un bon challenge ;)
#define ENTRY_TIME_LIMIT   3000 //Temps qu'on a pour appuyer sur un bouton avant de perdre. 
                           3000ms = 3 sec

#define MODE_MEMORY  0
#define MODE_BATTLE  1
#define MODE_BEEGEES 2

définition des variable de l'état du jeu

Pour que nous puissions stocker les différents états de jeu.

// Les variables de l'état du jeu
byte gameMode = MODE_MEMORY; //par défaut, on joue
byte gameBoard[32]; //contient les combinaisons de séquence au fur et à mesure de l'avancée du jeu
byte gameRound = 0; //compte le nombre de rounds gagnés par le joueur

Void setup

Etape 2

déclarer si on est en mode lecteur ou acteur de nos composants

INPUT_PULLUP, ou résistance de rappel

 //Permet de faire des pull-up dans les inputs
  pinMode(BUTTON_RED, INPUT_PULLUP);
  pinMode(BUTTON_GREEN, INPUT_PULLUP);
  pinMode(BUTTON_BLUE, INPUT_PULLUP);
  pinMode(BUTTON_YELLOW, INPUT_PULLUP);

  pinMode(LED_RED, OUTPUT);
  pinMode(LED_GREEN, OUTPUT);
  pinMode(LED_BLUE, OUTPUT);
  pinMode(LED_YELLOW, OUTPUT);

  pinMode(BUZZER1, OUTPUT);
  pinMode(BUZZER2, OUTPUT);

Tests pour lancer le jeu

 //Tests
  gameMode = MODE_MEMORY; // par défaut on lance le jeu

 // Test pour savoir si le bouton jaune a été pressé
 if (checkButton() == CHOICE_YELLOW) play_beegees();

Derniers tests avant de lancer le jeu

 // Test pour voir si le bouton vert est pressé
  if (checkButton() == CHOICE_GREEN)
  {
    gameMode = MODE_BATTLE; //Lance le jeu

    //Allume la led verte
    setLEDs(CHOICE_GREEN);
    toner(CHOICE_GREEN, 150);

    setLEDs(CHOICE_RED | CHOICE_BLUE | CHOICE_YELLOW); // Allume les autres leds jusqu'à 
                                                          ce que vous lachiez le bouton

    while(checkButton() != CHOICE_NONE) ; // Attends que le joueur ne presse plus le bouton

    //Maintenant attends. Le mode jeu va se lancer.
  }

  play_winner(); // Quand tu as réussi toutes les séquences, joue la musique du gagnant

Void loop

Etape 3

Initialisation du jeu

 attractMode(); // Fais clignoter les lumières jusqu'à ce que le joueur appuie sur un bouton

  // Indique comment doit commencer le jeu
  setLEDs(CHOICE_RED | CHOICE_GREEN | CHOICE_BLUE | CHOICE_YELLOW); // Turn all LEDs on
  delay(1000);
  setLEDs(CHOICE_OFF); // éteints les LEDs
  delay(250);

Qu'est-ce qui se passe quand on gagne ou on perd


  if (gameMode == MODE_MEMORY)
  {
    // Joue le jeu et renvoie le résultat
    if (play_memory() == true) 
      play_winner(); // le joueur a gagné, jouer la séquence musicale du gagnant
    else 
      play_loser(); // le joueur a perdu, jouer la séquence musicale du perdant
  }

  if (gameMode == MODE_BATTLE)
  {
    play_battle(); // joue jusqu'à ce que le joueur perde

    play_loser(); // le joueur a perdu, jouer la séquence musicale du perdant
  }
}

Les fonctions suivantes ne servent que au game play

Code pour le jeu de base "Simon Says"

Le jeu de base

boolean play_memory(void)
{
  randomSeed(millis()); // Génère un nombre random de millis()

  gameRound = 0; // Reset le jeu au début

  while (gameRound < ROUNDS_TO_WIN) 
  {
    add_to_moves(); // Ajoute un bouton à la séquence, puis la rejoue

    playMoves(); // Rejoue la séquence actuelle

    // puis attends que le joueur répète la séquence
    for (byte currentMove = 0 ; currentMove < gameRound ; currentMove++)
    {
      byte choice = wait_for_button(); // Check quel bouton le joueur a pressé

      if (choice == 0) return false; // Si le temps imparti est dépassé, le joueur perd

      if (choice != gameBoard[currentMove]) return false; // Si le choix est incorrect, le joueur perd
    }

    delay(1000); // Le joueur a réussi, attente avant la prochaine séquence
  }

  return true; // Le joueur a réussi toutes les 13 séquences et a gagné !
}

Retourne 0 si le joueur perd, ou 1 si le joueur a gagné

Code pour le Battle Mode :

un joueur contre un autre

Un joueur commence par appuyer sur un bouton puis passe la main à un autre joueur.

Celui-ci répète la séquence de son adversaire et ajoute un bouton. Le rend à l'autre joueur.

Et ce jusqu'à ce que quelqu'un perde :)

boolean play_battle(void)
{
  gameRound = 0; // Reset le jeu

  while (1) // tourne en boucle jusqu'à ce que quelqu'un perde
  {
    byte newButton = wait_for_button(); // Attend que l'autre joueur ajoute un bouton
    gameBoard[gameRound++] = newButton; // Ajoute ce nouveau bouton au tableau

    // puis demande à l'adversaire de répéter la séquence
    for (byte currentMove = 0 ; currentMove < gameRound ; currentMove++)
    {
      byte choice = wait_for_button();

      if (choice == 0) return false; // Si l'attente est trop longue, le joueur perd

      if (choice != gameBoard[currentMove]) return false; 
      // Si le choix est incorrect, le joueur perd
    }

    delay(100); // Donne au joueur un extra de 100ms pour laisser le temps aux joueurs 
    //de se passer les commandes
  }

  return true; 
}

Battle Mode

void playMoves(void)
{
  for (byte currentMove = 0 ; currentMove < gameRound ; currentMove++) 
  {
    toner(gameBoard[currentMove], 150);

    // Attend un peu avant que la séquence se rejoue
    // On peut raccourcir le temps pour rendre le jeu plus difficile
    delay(150); // 150 est un bon rythme. 75 ça devient difficile.
  }
}

// Ajoute un nouveau bouton random à la séquence de jeu
void add_to_moves(void)
{
  byte newButton = random(0, 4); //min (inclu), max (exclu)

  // On doit convertir ce chiffre, 0 à 3, en CHOICE
  if(newButton == 0) newButton = CHOICE_RED;
  else if(newButton == 1) newButton = CHOICE_GREEN;
  else if(newButton == 2) newButton = CHOICE_BLUE;
  else if(newButton == 3) newButton = CHOICE_YELLOW;

  gameBoard[gameRound++] = newButton; // Ajoute ce nouveau bouton au tableau de séquence
}

Joue les séquences de leds/son

Les fonctions suivantes ne servent que au hardware

void setLEDs(byte leds)
{
  if ((leds & CHOICE_RED) != 0)
    digitalWrite(LED_RED, HIGH);
  else
    digitalWrite(LED_RED, LOW);

  if ((leds & CHOICE_GREEN) != 0)
    digitalWrite(LED_GREEN, HIGH);
  else
    digitalWrite(LED_GREEN, LOW);

  if ((leds & CHOICE_BLUE) != 0)
    digitalWrite(LED_BLUE, HIGH);
  else
    digitalWrite(LED_BLUE, LOW);

  if ((leds & CHOICE_YELLOW) != 0)
    digitalWrite(LED_YELLOW, HIGH);
  else
    digitalWrite(LED_YELLOW, LOW);
}

Allume des leds
transforme l'information en byte

Attends que le bouton soit pressé.
Retourne une des leds de couleur (LED_RED, etc.) si c'est gagné, 0 si le temps est écoulé

byte wait_for_button(void)
{
  long startTime = millis(); // Se souvient de quand à commencé la séquence

  while ( (millis() - startTime) < ENTRY_TIME_LIMIT) // Boucle jusqu'à ce que trop de temps s'écoule
  {
    byte button = checkButton();

    if (button != CHOICE_NONE)
    { 
      toner(button, 150); // Joue le bouton que le joueur vient d'utiliser

      while(checkButton() != CHOICE_NONE) ;  // Attends que le joueur lache le bouton

      delay(10); // Aide à éviter les bugs si le joueur appuie deux fois accidentellement sur le bouton

      return button;
    }

  }

  return CHOICE_NONE; // Si on en arrive là, le temps est écoulé !
}

// Retourne un '1' bit à la position correspondant à CHOICE_RED, CHOICE_GREEN, etc.
byte checkButton(void)
{
  if (digitalRead(BUTTON_RED) == 0) return(CHOICE_RED); 
  else if (digitalRead(BUTTON_GREEN) == 0) return(CHOICE_GREEN); 
  else if (digitalRead(BUTTON_BLUE) == 0) return(CHOICE_BLUE); 
  else if (digitalRead(BUTTON_YELLOW) == 0) return(CHOICE_YELLOW);

  return(CHOICE_NONE); // Si aucun bouton n'est pressé, ne retourne rien
}

// Red, upper left:     440Hz - 2.272ms - 1.136ms pulse
// Green, upper right:  880Hz - 1.136ms - 0.568ms pulse
// Blue, lower left:    587.33Hz - 1.702ms - 0.851ms pulse
// Yellow, lower right: 784Hz - 1.276ms - 0.638ms pulse
void toner(byte which, int buzz_length_ms)
{
  setLEDs(which); //Allume une led particulière

  //joue la tonalité associée
  switch(which) 
  {
  case CHOICE_RED:
    buzz_sound(buzz_length_ms, 1136); 
    break;
  case CHOICE_GREEN:
    buzz_sound(buzz_length_ms, 568); 
    break;
  case CHOICE_BLUE:
    buzz_sound(buzz_length_ms, 851); 
    break;
  case CHOICE_YELLOW:
    buzz_sound(buzz_length_ms, 638); 
    break;
  }

  setLEDs(CHOICE_OFF); // Eteinds toutes les leds
}

Allume une led et joue une tonalité

void buzz_sound(int buzz_length_ms, int buzz_delay_us)
{
  // Converti le total des milliseconds en microseconds
  long buzz_length_us = buzz_length_ms * (long)1000;

  // Boucle jusqu'à ce que le temps de jeu restant soit à moins d'un buzz_delay_us
  while (buzz_length_us > (buzz_delay_us * 2))
  {
    buzz_length_us -= buzz_delay_us * 2; //Décrémente le temps restant de jeu

    // Bascule le buzzer à différentes vitesses
    digitalWrite(BUZZER1, LOW);
    digitalWrite(BUZZER2, HIGH);
    delayMicroseconds(buzz_delay_us);

    digitalWrite(BUZZER1, HIGH);
    digitalWrite(BUZZER2, LOW);
    delayMicroseconds(buzz_delay_us);
  }
}

Bascule tous les buzz_delay_us, pour une durée de buzz_length_ms

void play_winner(void)
{
  setLEDs(CHOICE_GREEN | CHOICE_BLUE);
  winner_sound();
  setLEDs(CHOICE_RED | CHOICE_YELLOW);
  winner_sound();
  setLEDs(CHOICE_GREEN | CHOICE_BLUE);
  winner_sound();
  setLEDs(CHOICE_RED | CHOICE_YELLOW);
  winner_sound();
}

Joue la séquence son et lumière du gagnant

void winner_sound(void)
{
  // Toggle the buzzer at various speeds
  for (byte x = 250 ; x > 70 ; x--)
  {
    for (byte y = 0 ; y < 3 ; y++)
    {
      digitalWrite(BUZZER2, HIGH);
      digitalWrite(BUZZER1, LOW);
      delayMicroseconds(x);

      digitalWrite(BUZZER2, LOW);
      digitalWrite(BUZZER1, HIGH);
      delayMicroseconds(x);
    }
  }
}

Joue le son du gagnant

void play_loser(void)
{
  setLEDs(CHOICE_RED | CHOICE_GREEN);
  buzz_sound(255, 1500);

  setLEDs(CHOICE_BLUE | CHOICE_YELLOW);
  buzz_sound(255, 1500);

  setLEDs(CHOICE_RED | CHOICE_GREEN);
  buzz_sound(255, 1500);

  setLEDs(CHOICE_BLUE | CHOICE_YELLOW);
  buzz_sound(255, 1500);
}

Joue la séquence son et lumière du perdant

void attractMode(void)
{
  while(1) 
  {
    setLEDs(CHOICE_RED);
    delay(100);
    if (checkButton() != CHOICE_NONE) return;

    setLEDs(CHOICE_BLUE);
    delay(100);
    if (checkButton() != CHOICE_NONE) return;

    setLEDs(CHOICE_GREEN);
    delay(100);
    if (checkButton() != CHOICE_NONE) return;

    setLEDs(CHOICE_YELLOW);
    delay(100);
    if (checkButton() != CHOICE_NONE) return;
  }
}

Montre un "attract mode" en attendant que le joueur lance le jeu :)

void attractMode(void)
{
  while(1) 
  {
    setLEDs(CHOICE_RED);
    delay(100);
    if (checkButton() != CHOICE_NONE) return;

    setLEDs(CHOICE_BLUE);
    delay(100);
    if (checkButton() != CHOICE_NONE) return;

    setLEDs(CHOICE_GREEN);
    delay(100);
    if (checkButton() != CHOICE_NONE) return;

    setLEDs(CHOICE_YELLOW);
    delay(100);
    if (checkButton() != CHOICE_NONE) return;
  }
}

Atelier 7 - "Simon Says"

Matériel

"Simon Says", c'est quoi ?

Ce que vous allez devoir faire ?

Les branchements

Définir les constantes

Etape 1

Les notes

Le choix des leds et des boutons

déclaration des pins

définition des paramètres du jeu

définition des variable de l'état du jeu

Void setup

Etape 2

déclarer si on est en mode lecteur ou acteur de nos composants

Tests pour lancer le jeu

Derniers tests avant de lancer le jeu

Void loop

Etape 3

Initialisation du jeu

Qu'est-ce qui se passe quand on gagne ou on perd

Les fonctions suivantes ne servent que au game play

Code pour le jeu de base "Simon Says"

Le jeu de base

Code pour le Battle Mode :

un joueur contre un autre

Battle Mode

Joue les séquences de leds/son

Les fonctions suivantes ne servent que au hardware

Allume des leds transforme l'information en byte

Attends que le bouton soit pressé. Retourne une des leds de couleur (LED_RED, etc.) si c'est gagné, 0 si le temps est écoulé

Allume une led et joue une tonalité

Bascule tous les buzz_delay_us, pour une durée de buzz_length_ms

Joue la séquence son et lumière du gagnant

Joue le son du gagnant

Joue la séquence son et lumière du perdant

Montre un "attract mode" en attendant que le joueur lance le jeu :)

Montre un "attract mode" en attendant que le joueur lance le jeu :)

Si vous avez été jusqu'ici votre jeu est fini ! Congrats ! Y'a plus qu'à jouer ;)

Allume des leds
transforme l'information en byte

Attends que le bouton soit pressé.
Retourne une des leds de couleur (LED_RED, etc.) si c'est gagné, 0 si le temps est écoulé