Introducció a SPARQL a partir de Wikidata

Toni Hermoso Pulido

@Toniher

Amical Wikimedia

https://w.wiki/Bw$

SPARQL Protocol

And

RDF Query Language

SPARQL

Resource Description Framework

RDF

Triples

Serialització RDF

Elements de Wikidata

Documentació a MediaWiki

JSON:

https://www.wikidata.org/wiki/Special:EntityData/Q1492.json

XML/RDF:

https://www.wikidata.org/wiki/Special:EntityData/Q1492.rdf

Turtle/RDF:

https://www.wikidata.org/wiki/Special:EntityData/Q1492.ttl

etc.

Accés de dades a Wikidata

SPARQL

#Gats
SELECT ?item
WHERE 
{
  ?item wdt:P31 wd:Q146 .
}

https://query.wikidata.org/

SPARQL

https://query.wikidata.org/

wdt: Properties

wd: Entities

...

others:

rdfs

schema

PREFIXES

SPARQL

#Gats
SELECT ?item ?itemLabel 
WHERE 
{
  ?item wdt:P31 wd:Q146 .
  ?item rdfs:label ?itemLabel .
}
https://w.wiki/Buw

 

SPARQL

#Gats
SELECT ?item ?itemLabel 
WHERE 
{
  ?item wdt:P31 wd:Q146 ;
        rdfs:label ?itemLabel .
}
https://w.wiki/Buy

SPARQL

#Gats
SELECT ?item ?itemLabel 
WHERE 
{
  ?item wdt:P31 wd:Q146 ;
        rdfs:label ?itemLabel .
  FILTER(LANG(?itemLabel) = "ca").
}
https://w.wiki/Buz

SPARQL

#Gats
SELECT ?item ?itemLabel 
WHERE 
{
  ?item wdt:P31 wd:Q146 .
  SERVICE wikibase:label 
  { 
    bd:serviceParam wikibase:language "ca". 
  }
}


https://w.wiki/Bu$

SPARQL

#Gats
SELECT ?item ?itemLabel 
WHERE 
{
  ?item wdt:P31 wd:Q146 .
  SERVICE wikibase:label 
  { 
    bd:serviceParam wikibase:language "es,fr,ca". 
  }
}
ORDER BY ?itemLabel
LIMIT 10

https://w.wiki/Bv2

SPARQL

#Matemàtiques i polítiques

SELECT ?item ?itemLabel WHERE {
  ?item wdt:P31 wd:Q5;
    wdt:P106 wd:Q170790, wd:Q82955;
    rdfs:label ?itemLabel .
  ?item wdt:P21 wd:Q6581072 .
}
https://w.wiki/Bv5

SPARQL

#Matemàtiques i polítiques

SELECT ?item ?itemLabel WHERE {
  ?item wdt:P31 wd:Q5;
    wdt:P106 wd:Q170790, wd:Q82955;
    rdfs:label ?itemLabel .
  ?item wdt:P21 wd:Q6581072 .
  FILTER(LANG(?itemLabel) = "ca") .
 }
https://w.wiki/Bv6

SPARQL

#Matemàtiques i polítiques

SELECT ?item ?itemLabel ?itemDescription WHERE {
  ?item wdt:P31 wd:Q5;
    wdt:P106 wd:Q170790, wd:Q82955;
    rdfs:label ?itemLabel ;
    schema:description ?itemDescription .
  ?item wdt:P21 wd:Q6581072 .
  FILTER(LANG(?itemLabel) = "ca") .
  FILTER(LANG(?itemDescription) = "ca") .
  
 }
https://w.wiki/Bv7

SPARQL

#Matemàtiques i polítiques

SELECT ?item ?itemLabel WHERE {
  ?item wdt:P31 wd:Q5;
    wdt:P106 wd:Q170790, wd:Q82955 .
  ?item wdt:P21 wd:Q6581072 .
  SERVICE wikibase:label 
  { 
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],ca". 
  }
}
https://w.wiki/Bv8

SPARQL

#Matemàtiques i polítiques amb imatges

SELECT DISTINCT ?item ?itemLabel ?image WHERE {
  ?item wdt:P31 wd:Q5;
    wdt:P106 wd:Q170790, wd:Q82955 .
  ?item wdt:P21 wd:Q6581072 .
  ?item wdt:P18 ?image .
  SERVICE wikibase:label 
  { 
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],ca". 
  }
}
https://w.wiki/Bv9

SPARQL

#Matemàtiques i polítiques amb imatges opcionals

SELECT DISTINCT ?item ?itemLabel ?image WHERE {
  ?item wdt:P31 wd:Q5;
    wdt:P106 wd:Q170790, wd:Q82955 .
  ?item wdt:P21 wd:Q6581072 .
  OPTIONAL {
  	?item wdt:P18 ?image .
  }
  SERVICE wikibase:label 
  { 
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],ca". 
  }
}
https://w.wiki/BvC

SPARQL

#Matemàtiques i polítiques només amb imatges

SELECT DISTINCT ?item ?itemLabel ?image WHERE {
  ?item wdt:P31 wd:Q5;
    wdt:P106 wd:Q170790, wd:Q82955 .
  ?item wdt:P21 wd:Q6581072 .
  FILTER EXISTS {
  	?item wdt:P18 ?image .
  }
  SERVICE wikibase:label 
  { 
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],ca". 
  }
}
https://w.wiki/BvD

SPARQL

#Matemàtiques i polítiques sense imatges
SELECT DISTINCT ?item ?itemLabel ?image WHERE {
  ?item wdt:P31 wd:Q5;
    wdt:P106 wd:Q170790, wd:Q82955 .
  ?item wdt:P21 wd:Q6581072 .
  FILTER NOT EXISTS {
  	?item wdt:P18 ?image .
  }
  SERVICE wikibase:label 
  { 
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],ca". 
  }
}
https://w.wiki/BvE

SPARQL

https://w.wiki/BvH
#Matemàtiques i polítiques amb imatges opcionals 
#nascudes després del 1961

SELECT DISTINCT ?item ?itemLabel ?born ?image WHERE {
  ?item wdt:P31 wd:Q5;
    wdt:P106 wd:Q170790, wd:Q82955 .
  ?item wdt:P21 wd:Q6581072 ;
        wdt:P569 ?born .
  FILTER (?born >= "1961-01-01T00:00:00Z"^^xsd:dateTime) .
  OPTIONAL {
  	?item wdt:P18 ?image .
  }
  SERVICE wikibase:label 
  { 
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],ca". 
  }
}

SPARQL

https://w.wiki/BvJ
# Subclasses de matemàtic

SELECT DISTINCT ?item ?itemLabel WHERE {
  ?item wdt:P279* wd:Q170790;
  SERVICE wikibase:label { 
  	bd:serviceParam wikibase:language "[AUTO_LANGUAGE],ca". 
  }
}

SPARQL

https://w.wiki/BvL
#Matemàtiques (ampli) amb imatges opcionals 
#nascudes després del 1961

SELECT DISTINCT ?item ?born ?image WHERE {
  ?item wdt:P31 wd:Q5;
    wdt:P106/wdt:P279* wd:Q170790;
    wdt:P21 wd:Q6581072;
    wdt:P569 ?born.
  FILTER(?born >= "1961-01-01T00:00:00Z"^^xsd:dateTime)
  OPTIONAL { ?item wdt:P18 ?image. }
  SERVICE wikibase:label { 
  	bd:serviceParam wikibase:language "[AUTO_LANGUAGE],ca". 
  }
}

SPARQL

https://w.wiki/BvM
#Matemàtiques (ampli) amb imatges opcionals 
#nascudes després del 1961 i amb lloc de naixement conegut

SELECT DISTINCT ?item ?born ?birthPlace ?image WHERE {
  ?item wdt:P31 wd:Q5;
    wdt:P106/wdt:P279* wd:Q170790;
    wdt:P21 wd:Q6581072;
    wdt:P569 ?born ;
    wdt:P19 ?birthPlace .
  FILTER(?born >= "1961-01-01T00:00:00Z"^^xsd:dateTime)
  OPTIONAL { ?item wdt:P18 ?image. }
  SERVICE wikibase:label { 
  	bd:serviceParam wikibase:language "[AUTO_LANGUAGE],ca". 
  }
}

SPARQL

https://w.wiki/BvN
#Matemàtiques (ampli) amb imatges opcionals 
#nascudes després del 1961 i amb lloc de naixement conegut

SELECT DISTINCT ?item ?born ?birthPlace ?coordinate ?image WHERE {
  ?item wdt:P31 wd:Q5;
    wdt:P106/wdt:P279* wd:Q170790;
    wdt:P21 wd:Q6581072;
    wdt:P569 ?born ;
    wdt:P19 ?birthPlace .
    ?birthPlace wdt:P625 ?coordinate .
  FILTER(?born >= "1961-01-01T00:00:00Z"^^xsd:dateTime)
  OPTIONAL { ?item wdt:P18 ?image. }
  SERVICE wikibase:label { 
  	bd:serviceParam wikibase:language "[AUTO_LANGUAGE],ca". 
  }
}

Més informació