drug repurposing by hetnet relationship prediction:

A NEW HOPE

Daniel Himmelstein

iPQB Journal Club

Leap Day 2016

Slides online at http://slides.com/dhimmel/a-new-hope

// Find CbGiGpBP where first gene is expressed in the CNS
MATCH (n0:Compound)
OPTIONAL MATCH paths = 
  (n0)-[:BINDS_CbG]-(n1)-[:INTERACTS_GiG]-(n2)-[:PARTICIPATES_GpBP]-(n3:BiologicalProcess)
WHERE n3.identifier = 'GO:0042552' // myelination
AND exists((:Anatomy {identifier: 'UBERON:0001017'})-[:EXPRESSES_AeG]-(n1))
WITH
  n0 AS source, paths,
  // Extract the degrees along each path
  [
    size((n0)-[:BINDS_CbG]-()),
    size(()-[:BINDS_CbG]-(n1)),
    size((n1)-[:INTERACTS_GiG]-()),
    size(()-[:INTERACTS_GiG]-(n2)),
    size((n2)-[:PARTICIPATES_GpBP]-()),
    size(()-[:PARTICIPATES_GpBP]-(n3))
  ] AS degrees
RETURN
  source.identifier AS drugbank_id,
  source.name AS drugbank_name,
  count(paths) AS path_count,
  sum(reduce(pdp = 1.0, d in degrees| pdp * d ^ -0.5)) AS DWPC
ORDER BY DWPC DESC, drugbank_name

Candidate compounds for remyelination

download database

// Find CbGiGpBP paths between Marimastat and myelination
MATCH paths = 
  (n0:Compound)-[:BINDS_CbG]-(n1)-[:INTERACTS_GiG]-(n2)
               -[:PARTICIPATES_GpBP]-(n3:BiologicalProcess)
WHERE n0.identifier = 'DB00786' // Marimastat
  AND n3.identifier = 'GO:0042552' // myelination
  // Expressed in the central nervous system
  AND exists((:Anatomy {identifier: 'UBERON:0001017'})-[:EXPRESSES_AeG]-(n1))
RETURN paths

Paths for marimastat–myelination